Eigenschaft: Font.Name (TLabel)

Verweis:	Font-Dialog Bedienung
Uses:	StdCtrls
Eingabe:	Name der zu benutzenden Schriftart als String.
Ausgabe:	Ausgabe der Schrift in der Schriftart
Funktion:	Ordnet einer oder mehrerer Komponenten eine Schriftart zu.

Beispiel 1

Vorbereitung: Erstellen sie eine IDE Anwendung und ziehen Sie eine TLabel auf die Form. Erstellen Sie zusätzlich ein OnActivate-Ereignis.

procedure TForm1.FormActivate(Sender: TObject);
begin
  Label1.Font.Name := 'Hip Hop';
end;

Font.Name ruft eine Schriftart für die entsprechende Komponente mit seinem Namen auf. Dieser Befehl findet aber nur Gehör, wenn der entsprechende Name der Schriftart auf dem Rechner installiert ist. Wenn nicht, so wie in unserem ersten Beispiel, passiert nichts. Es bleibt die alte Schriftart erhalten. Wir müssen also Prüfen ob eine Schriftart auf dem Zielsystem existiert. So wie die Komponente FontDialog es tut.

Beispiel 2

Vorbereitung: Erstellen sie eine IDE Anwendung und ziehen Sie eine TListBox auf die Form. Erstellen Sie zusätzlich ein OnActivate-Ereignis.

procedure TForm1.FormActivate(Sender: TObject);
begin
  Listbox1.Align := alClient;
  Listbox1.Clear;
  ListBox1.Sorted := True;
  ListBox1.Items := Screen.Fonts;
end;

Im 2. Beispiel sehen Sie wie wir uns die Namen der zur Verfügung stehenden Schriftarten anzeigen lassen können. In dem Beispiel übergeben wir die Stringlist der Funktion Screen.Fonts an unsere Listbox1 und lassen uns diese Liste sortiert anzeigen.

Beispiel 3

Vorbereitung: Erstellen Sie eine IDE Anwendung und ziehen Sie ein TButton und ein TLabel auf die Form. Erstellen Sie zusätzlich ein OnClick-Ereignis für Button1.

procedure TForm1.Button1Click(Sender: TObject);
begin
  if Screen.Fonts.IndexOf('Hip Hop') >= 0 then
  begin
    ShowMessage('Hurra! Schriftart "Hip Hop" wurde Gefunden.');
    Label1.Font.Name := 'Hip Hop';
  end
  else
  begin
    ShowMessage('Schriftart "Hip Hop" wurde nicht Gefunden.');
    if Screen.Fonts.IndexOf('Arial') > -1 then
    begin
      ShowMessage('Schalte auf "Arial".');
      Label1.Font.Name := 'Arial';
      Label1.Font.Height := 50;
    end
    else
      ShowMessage('Behalte die Alte Schriftart.' + LineEnding +
        'Da weder "Hip Hop" noch "Arial" installiert ist.');
  end;
end;

In Beispiel 3 fragen wir ab ob die Schriftart „Hip Hop“ installiert ist, sollte dies nicht der Fall sein ersetzen wir diese Schriftart durch „Arial“ wenn diese auch nicht vorhanden sein sollte, dann geben wir noch die Meldung raus, dass nichts verändert wurde.

Beispiel 4

Vorbereitung: Erstellen sie eine IDE Anwendung und ziehen Sie eine TLabel und eine TCombobox auf die Form. Erstellen Sie zusätzlich ein OnChange-Ereignis für die Combox und zusätzlich ein OnActivate-Ereignis für die Form.

procedure TForm1.ComboBox1Change(Sender: TObject);
begin
  //Weise dem Label die Schriftart zu
  Label1.Font.Name := ComboBox1.Text;
  //Zeige den Namen an
  Label1.Caption := Label1.Font.Name;
end;

procedure TForm1.FormActivate(Sender: TObject);
begin
  // Lösche und Sortiere
  ComboBox1.Clear;
  ComboBox1.Sorted := True;
  // Lade die Fontnamen in die Box
  ComboBox1.Items := Screen.Fonts;
  // Formatierung
  ComboBox1.Align := alBottom;
  Label1.Left := 0;
  Label1.Top := 0;
end;

In Beispiel 4 überlassen wir die Auswahl des Schriftsatzes dem Benutzer. Ob das „gut“ oder „schlecht“ ist hängt von der Anwendung und dem Nutzer ab. Zunächst einmal hat er eine freie Gestaltungsmöglichkeit, aber genau dies kann bei einem Anfänger der 1000 Schriftsätze installiert hat, zu einer Überforderung führen.